工作中或多或少有些琐碎的事情，比如每天要发送和接受数据，很多是通过邮件的方式传递的。之前写过如何在Outlook里自动保存附件，这里再发一个如何更方便地发送带附件的邮件。

主要是针对下面这个需求：每天需要发送一些特定的附件给特定的人，邮件有差不多固定格式的标题和正文，所带附件文件名的格式也比较固定，比如以当天日期为文件名的文件。

下载下面的vbs脚本随便放到某个地方，点击运行，将自动调用Outlook建立一封邮件（机器里需安装Office Outlook），自动填入预先指定的收件人，邮件标题为 "报告 2010-12-9"（后面日期可根据当天日期自动改变），并且载入D盘根目录下的"report 2010-12-9.docx"和"report 2010-12-9.pdf"作为附件。

可对其进行自定义，用写字板打开这个vbs文件，修改下面这段即可：

' receiptions 为收件人列表
' Subject 为邮件标题
' Body 为邮件正文
' Attachments 为附件列表，每个附件都需附带路径。
' autoSend 设置是否直接发送，设置为False时将停留在最后窗口，需手动按Outlook的发送按钮进行发送

receiptions = "math.zqy@gmail.com; blog@zhiqiang.org"
Subject = "报告 " & sdt
Body = "附件是今日报告，请查收。"
Attachments = Array("D:\report " & sdt & ".docx", "D:\report " & sdt & ".pdf")
autoSend = False

该脚本需要你使用Outlook作为邮件软件，上面的脚本在Outlook 2007下测试通过，但在别的版本下应该也能用的。对于Outlook Express和Lotus都能实现同样的东西，这里不阐述了。

© zhiqiang for 阅微堂, 2010. | 链接 | 1条评论

Excel有一个很有用的功能是直接导入外部数据库或者使用外部数据源建立数据透视表和数据透视图。但比较可惜的是，这个数据源的查询语句是静态的，它无法根据日期自动修改（比如在应用中，我们希望每天获取的外部数据都是当天最新的数据），下面两个函数是修改外部数据源的VBA代码，调用它们就可以建立动态的数据源。

' 更改数据表的来源
' wb：工作表对象
' connectionName：数据来源连接名称
' strSQL：新查询语句（修改SQL的查询代码）
' strSQLConnection：新连接语句（修改来源数据库，在对DBF数据库操作时非常有用）
' author: zhang@zhiqiang.org, 2010
Public Sub ChangeODBCConnection(wb As Excel.Workbook, connectionName As String, _
        Optional strSQL As String = "", Optional strSQLConnection As String = "")

    With wb.Connections(connectionName).ODBCConnection
        If Len(strSQLConnection) Then .CommandText = SplitString(strSQLConnection)
        If Len(strSQL) Then .Connection = SplitString(strSQL)
    End With
    wb.Connections(connectionName).Refresh
End Sub

' 更改数据表的来源
' pc：数据透视表的PivotCache对象 （例如：ActiveSheet.PivotTables(1).PivotCache）
' connectionName：数据来源连接名称
' strSQL：新查询语句（修改SQL的查询代码）
' strSQLConnection：新连接语句（修改来源数据库，在对DBF数据库操作时非常有用）
' author: zhang@zhiqiang.org, 2010
Public Sub ChangePivotConnection(pc As Excel.PivotCache, Optional strSQLConnect, _
        Optional strSQL As String = "")
    Dim blnODBCConnect As Boolean

    With pc
        If .QueryType = xlODBCQuery Then
            blnODBCConnect = True
            If Len(strSQLConnect) = 0 Then strSQLConnect = .Connection
            strSQLConnect = Replace(strSQLConnect, "ODBC;DSN", "OLEDB;DSN", 1, 1, vbTextCompare)
        End If

        If StrComp(.Connection, strSQLConnect, vbTextCompare) <> 0 And Len(strSQLConnect) Then
            .Connection = strSQLConnect
        End If

        If StrComp(.CommandText, strSQL, vbTextCompare) <> 0 And Len(strSQL) Then
            .CommandText = (strSQL)
        End If

        If blnODBCConnect = True Then
            .Connection = Replace(.Connection, "OLEDB;DSN", "ODBC;DSN", 1, 1, vbTextCompare)
        End If

        .Refresh
    End With
End Sub

' 将字符串分割成短字符串的数组
Private Function SplitString(ByVal s As String) As Variant
    Dim ss() As Variant
    Dim i As Long

    ReDim ss(0 To Len(s) \ 200) ' note: it is not 256
    For i = 0 To UBound(ss)
        ss(i) = Array(Mid(s, i * 200 + 1, 200))
    Next i

    SplitString = ss
End Function

以上代码在Office 2007版通过测试，其余版本未知。

© zhiqiang for 阅微堂, 2010. | 链接 | 2 条评论

在工作中定期或不定期会收到一些数据文件，然后要将它们的附件保存到自己的电脑上，下面演示如何让Outlook自动做这件事情。

首先，下面的SaveAttach函数可以保存附件中的docx文档到D盘根目录下。用ALT+F11打开VBA编辑器，插入下述代码：

Public Sub SaveAttach(Item As Outlook.MailItem)
    SaveAttachment Item, "D:\", "*.docx"
    ' MsgBox "附件已保存"
End Sub

' 保存附件
' path为保存路径，condition为附件名匹配条件
Private Sub SaveAttachment(ByVal Item As Object, path$, Optional condition$ = "*")
    Dim olAtt As Attachment
    Dim i As Integer

    If Item.Attachments.Count > 0 Then
        For i = 1 To Item.Attachments.Count
            Set olAtt = Item.Attachments(i)
            ' save the attachment
            If olAtt.FileName Like condition Then
                olAtt.SaveAsFile path & olAtt.FileName
            End If
        Next
    End If
    Set olAtt = Nothing
End Sub

如何实现自动保存呢？利用Office Outlook 2007的规则，它可以设定对满足一定条件的邮件自动运行脚本，然后选择脚本为SaveAttach函数即可。这样便能实现收到某些邮件时自动保存符合条件的附件到相应文件目录。

补充：如果上面方法没效果，可以尝试修改下面的设置（由wfustc在留言中指出）

在Outlook的信任中心勾选上“允许使用脚本”。

对于Outlook 2007，在“工具->信任中心->电子邮件安全性->文件夹中的脚本"，勾选上"允许在公用文件夹中使用脚本"和"允许在共享文件夹中使用脚本"

对于Outlook 2010，相应选项位于“文件->选项->信任中心->电子邮件安全性"里。

© zhiqiang for 阅微堂, 2009. | 链接 | 21 条评论

时间管理中有重要的一条，保持你的收件箱整洁、干净。Gmail一个重要的创新就是Archive（存档），选中邮件后点下“archive”按钮或者按一下快捷键y，邮件就被移出收件箱，但又跟删除邮件不一样，这些邮件还可以继续被搜索。这里讲最近写的如何在Outlook里实现这个功能。

效果：按快捷键ALT+Y或者点击工具栏上的“存档”按钮，选中的邮件自动转移到事先设定好的存档文件夹内。

实现方法：

1. 在收件箱下建立存档文件夹，文件夹名为“存档”。

2. 核心工具是macro(宏)，具体讲是一段vba代码。按ALT+F11，打开VBA编辑器，展开左侧的Project1，输入下列代码：

Sub ArchiveEmail()
    Dim destFolder As Outlook.folder
    Dim sel As Outlook.Selection, item As Outlook.MailItem
    Set destFolder = Outlook.Application.GetNamespace("MAPI").GetDefaultFolder(olFolderInbox).Folders("存档")
    Set sel = Application.ActiveExplorer.Selection

    For Each item In sel
        item.Move destFolder
    Next item
End Sub

3. 接下来我们要做的两个事情，设置快捷键和在工具栏上放置按钮。不同于Excel中可以给自定义宏设置快捷键，Outlook无法直接给自定义宏设置快捷键，只有通过将宏放在工具栏上来间接实现。

• Outlook主界面的工具栏上点右键 –> 自定义 –> 重排命令，选择常用工具栏
• 点击添加，选中“宏”中的Project1-ThisOutlookSession-ArchiveEmail后确定。
• 将刚才添加的宏上移或者下移到喜欢的位置，我把它放在“删除(D)”的下面。
• 点右侧的更改所选内容，将其命名改为“存档(&Y)”，还可以给按钮选一个比较好看的按钮图像，我选的是笑脸符号。

以上在Office 2007+Win XP上试验通过。

© zhiqiang for 阅微堂, 2009. | 链接 | 12 条评论